"Solución, por la vía matricial, de un sistema de ecuaciones lineales de primer orden con raices reales y distintas";

"Solución manual";

"Cálculo de los elementos necesarios para obtener la solución";
"Matriz"
A = {{1,1},{-2,4}};
MatrixForm[A]
"Primer valor propio y su vector propio"
ValProp=Eigenvalues[A];
VectProp=Eigenvectors[A];
{ValProp[[1]],MatrixForm[VectProp[[1]]]}
"Segundo valor propio y su vector propio"
{ValProp[[2]],MatrixForm[VectProp[[2]]]}

"Solución vectorial y de cada variable";

"Solución"
solucion=c1*E^(ValProp[[1]]*t)*VectProp[[1]]+c2*E^(ValProp[[2]]*t)*VectProp[[2]];
MatrixForm[solucion]
"Solución de x(t)"
solxx=solucion[[1]]
"Solución de y(t)"
solyy=solucion[[2]]
"Soluciones para x(0)=1 e y(0)=3, esto es para si c1=2 y c2=-1"
xx00=solxx/.c1->2/.c2->-1
yy00=solyy/.c1->2/.c2->-1
"Comprobación"
xx00/.t->0
yy00/.t->0

"Solución directa por Mathematica y representación";
sol=DSolve[{x'[t]==x[t]+y[t],y'[t]==-2*x[t]+4*y[t],x[0]==1,y[0]==3},{x[t],y[t]},t];
"Soluciones de x[t] y de y[t]"
sol[[1,1,2]]
sol[[1,2,2]]
"Representación"
Plot[{sol[[1,1,2]],sol[[1,2,2]]},{t,0,1},PlotStyle->Thick]
"Trayectoria"
ParametricPlot[{sol[[1,1,2]],sol[[1,2,2]]},{t,0,1},AxesOrigin->{0,0},PlotRange->{{0,70},{0,70}},AspectRatio->1, PlotStyle->Thick]